18b20程序及應(yīng)用

DS18B20原理及引腳介紹
  DS18B20數(shù)字溫度計是DALLAS公司生產(chǎn)的1－Wire，即單總線器件，具有線路簡單，體積小的特點。因此用它來組成一個測溫系統(tǒng)，具有線路簡單，在一根通信線，可以掛很多這樣的數(shù)字溫度計，十分方便。DS18B20產(chǎn)品的特點
　?。?）、只要求一個端口即可實現(xiàn)通信。
　?。?）、在DS18B20中的每個器件上都有獨一無二的序列號。
　　（3）、實際應(yīng)用中不需要外部任何元器件即可實現(xiàn)測溫。
　?。?）、測量溫度范圍在－55。C到＋125。C之間。
　?。?）、數(shù)字溫度計的分辨率用戶可以從9位到12位選擇。
　?。?）、內(nèi)部有溫度上、下限告警設(shè)置。
TO－92封裝的DS18B20的引腳排列見下圖，其引腳功能描述見下：

1．GND
 地信號
2．DQ
 數(shù)據(jù)輸入/輸出引腳。開漏單總線接口引腳。當(dāng)被用著在寄生電源下，也可以向器件提供電源。
3．VDD
 可選擇的VDD引腳。當(dāng)工作于寄生電源時，此引腳必須接地。

18b20應(yīng)用電路圖

18B20控制命令字
                       18B20的ROM命令
指令                    說明
讀ROM(33H) 讀18B20的序列號
匹配ROM(55H) 繼續(xù)讀完64位序列號的命令,用于多個18B20時定位
跳過ROM(CCH) 此命令執(zhí)行后的在存儲器打操作針對在線所有18B20
搜ROM(F0H) 識別總線上各器件的編碼,為操作各器件做準(zhǔn)備
報警搜索(ECH) 公溫度越限的器件對此命令作出響應(yīng)
                     18B20存儲控制命令
     指令                    說明
溫度轉(zhuǎn)換(44H) 啟動在線ds18B20做溫度AD轉(zhuǎn)換
讀數(shù)據(jù)(BEH) 從高速暫存器讀9位溫度值和CRC值
寫數(shù)據(jù)(4EH) 將數(shù)據(jù)寫入高速暫存的第3和第4字節(jié)中
復(fù)制(48H) 將高速暫存器中第3和第4字節(jié)復(fù)制到EERAM
讀EERAM(B8H) 將EERAM內(nèi)容寫入高速暫存器中第3和第4字節(jié)
讀電源供電方式(B4H) 了解18B20的供電方式

18b20程序

  WENDU_L EQU 29H;用于保存讀出溫度的低字節(jié)
   WENDU_H EQU 28H;用于保存讀出溫度的高字節(jié)
   XIAOSHU EQU 27H;用于保存溫度的小數(shù)部分
   ZHENGSHU EQU 26H;用于保存整數(shù)部分
   BIAOZHI BIT 50H;18B20檢查位1為存在，0為不存在
   ORG  0000H
   AJMP MAIN
   ORG 0030H
MAIN:MOV SCON,#00H
    ACALL DUWEN
     ACALL ZHENGHE
  ACALL BCD
  ACALL DISP
  ACALL TIME1
  AJMP MAIN
;----------------------------------------------------------------------------------------------------------------------------------------
;讀溫度子程序
;----------------------------------------------------------------------------------------------------------------------------------------
DUWEN:SETB P2.0
      ACALL FUWEI      ;讀溫度之前必須先復(fù)位
      JB BIAOZHI,CUNZAI;查看標(biāo)志位看18B20是否存在，1為存在，0為不存在
   RET               ;不存在則返回
CUNZAI:                 ;存在則開始讀溫度
     MOV A,#0CCH        ;跳過ROM匹配
  ACALL XIE          ;調(diào)寫子程序
  MOV A,#44H         ;發(fā)出溫度轉(zhuǎn)換命令
  ACALL XIE          ;調(diào)寫子程序
  ACALL TIME1        ;調(diào)1秒延時,等等AD轉(zhuǎn)換完成,現(xiàn)在分辨率為12位,溫度最大轉(zhuǎn)換時間為750MS
  ACALL FUWEI        ;讀溫前需要復(fù)位
  MOV A,#0CCH        ;跳過ROM匹配
  ACALL XIE         
  MOV A,#0BEH        ;發(fā)讀溫度命令
     ACALL XIE
  ACALL DUSHU        ;將闈出數(shù)據(jù)讀回
  CLR P1.2
  RET
;------------------------------------------------------------------------------------------------------------------------------
;復(fù)位子程序
;18B20復(fù)位需要將數(shù)據(jù)位拉低500us
;18B20收到信號后要等待16-60us,然后發(fā)出60-240us的低脈沖
;-------------------------------------------------------------------------------------------------------------------------------
FUWEI:SETB P2.0
      NOP
   CLR P2.0
   MOV R0,#3
INTE:MOV R1,#107      ;設(shè)一個537us延時
KK1: DJNZ R1,KK1
   DJNZ R0,INTE
   SETB P2.0    ;拉高數(shù)據(jù)線,等待回應(yīng)
   NOP
   NOP
   NOP
   MOV R0,#25  ;
INTE1:JNB P2.0,INTE2    ;延時延時50us等待18B20回應(yīng),若返回低脈沖則說明18B20存在
   DJNZ R0 ,INTE1
   AJMP INTE3        ;經(jīng)過反應(yīng)時間而沒檢測到18B20的存在,則跳轉(zhuǎn)去清零標(biāo)志位
INTE2:SETB BIAOZHI      ;檢測到18B20存在,置1標(biāo)志位
      CLR P1.0
      AJMP INTE4
INTE3:CLR BIAOZHI       ;沒檢測到18B20,清零標(biāo)志位
      AJMP INTE5
INTE4:MOV R0,#120     ;延時240us,確定回應(yīng)信號已發(fā)完
 KK:  DJNZ R0,KK
INTE5:SETB P2.0
       RET 

;----------------------------------------------------------------------------------------------------------------------------------------
;寫18B20子程序
;-----------------------------------------------------------------------------------------------------------------------------------------
XIE:MOV R2,#8           ;寫計數(shù)寄存器，一共有8位數(shù)據(jù)
    CLR C
LP:CLR P2.0
 MOV R3,#6   ;設(shè)一個延時
LL1:DJNZ R3,LL1
    RRC A    ;右循環(huán)，先輸出低位
    MOV P2.0,C     
    MOV R3,#23   ;設(shè)延時
LL: DJNZ R3,LL   ;
    SETB P2.0
    NOP
    NOP
    DJNZ R2,LP           ;判斷是否完成數(shù)據(jù)傳送
    SETB P2.0            ;完成傳送拉高數(shù)據(jù)位
    RET
;-----------------------------------------------------------------------------------------------------------------------------------------
;從18B20中讀出溫度數(shù)據(jù)子程序
;-----------------------------------------------------------------------------------------------------------------------------------------
 
DUSHU:MOV R4,#2         ;設(shè)讀回數(shù)據(jù)個數(shù)指針
      MOV R1,#WENDU_L   ;把溫度數(shù)據(jù)低位存入29H
RE:   MOV R2,#8         ;設(shè)數(shù)據(jù)長度指針
RE1:  CLR  C
      SETB P2.0
   NOP
   NOP
   CLR P2.0
   NOP
   NOP
   NOP
   SETB P2.0
   MOV R3,#9   
   DJNZ R3,$
   MOV C,P2.0
   MOV R3,#23
NN:   DJNZ R3,NN
   RRC  A
   DJNZ R2,RE1
   MOV @R1,A     
   DEC R1   ;高位存入28H
   DJNZ R4,RE
   RET
 
;---------------------------------------------------------------------------------------------------------------------------------
;數(shù)據(jù)整合子程序
;溫度源數(shù)據(jù)的整合,讀出數(shù)據(jù)的高字節(jié)的低四位決定溫度的整數(shù)部分
;低字節(jié)的低四位決定小數(shù)部分
;-----------------------------------------------------------------------------------------------------------------------------
ZHENGHE:MOV A,#0FH
        ANL A,WENDU_L ;低字節(jié)的低四位就是小數(shù)部分
  MOV XIAOSHU,A   ;獲得小數(shù)部分
  MOV A,WENDU_L ;將高字節(jié)的低四位移入低字節(jié)的高4位,
  MOV C,40H  ;獲得的新字節(jié)就是整數(shù)部分的數(shù)據(jù)
  RRC A
  MOV C,41H
  RRC A
  MOV C,42H
  RRC A
  MOV C,43H
  RRC A
  MOV ZHENGSHU,A
  RET
;-----------------------------------------------------------------------------------------------------------------------------------------
;顯示數(shù)據(jù)拆解程序、顯示程序、延時程序
;----------------------------------------------------------------------------------------------------------------------------------------
;數(shù)據(jù)拆解程序
BCD:MOV A,ZHENGSHU
    MOV B,#10
 DIV AB
 MOV 50H,A
 MOV 51H,B
 MOV A,XIAOSHU
 MOV R0,#52H
 MOV R2,#4
 D0:MOV B,#10
    MUL AB
 MOV B,#16
 DIV AB
 MOV @R0,A
 INC R0
 MOV A,B
 DJNZ R2,D0
 RET
;-----------------------------------
;顯示程序
;----------------------------------
DISP:ACALL TIME
     MOV R7,#6
     MOV DPTR,#TAB
  MOV R0,#55H
LP1:MOV A ,@R0;
 
 MOVC A,@A+DPTR
   CJNE R7,#2,NE1
   ANL A,#07FH
NE1:MOV SBUF,A
    JNB TI ,$
 CLR TI
 DEC R0
 DJNZ R7,LP1
 RET
;----------------------------------------
;延時程序
;----------------------------------------
TIME1:MOV R6,#4
LOOP2:MOV R5,#250
LOOP1:ACALL D1MS
     DJNZ R5,LOOP1
  DJNZ R6,LOOP2
  RET
TIME:MOV R6,#200
LOOP3:ACALL D1MS
    DJNZ R6,LOOP3
 RET
D1MS:MOV R7,#250
LOOP0:NOP
      NOP
   NOP
   DJNZ R7,LOOP0
   RET
TAB:DB 0C0H,0F9H,0A4H,0B0H 
     DB 99H, 92H, 82H, 0F8H 
     DB 80H, 90H, 88H, 83H  
     DB 0C6H,0A1H,86H, 8EH  
     DB 0FFH                
     END

18B20溫度傳感器溫度計程序