鴻蒙內(nèi)核源碼分析之為何要有異常接管?

為何要有異常接管?

拿小孩成長(zhǎng)打比方,大人總希望孩子能健康成長(zhǎng),但在成長(zhǎng)過(guò)程中總會(huì)遇到各種各樣的問(wèn)題,樹(shù)欲靜而風(fēng)不止,成長(zhǎng)路上有危險(xiǎn),有時(shí)是自己的問(wèn)題有時(shí)是外在環(huán)境問(wèn)題.就像抖音最近的流行口水歌一樣,社會(huì)很單純,復(fù)雜的是人啊,每次聽(tīng)到都想站起來(lái)扭幾下.哎! 老衲到底做錯(cuò)什么了?

比如:老被其他小朋友欺負(fù)怎么弄? 發(fā)現(xiàn)亂花錢(qián)怎么搞? 青春期發(fā)育怎么應(yīng)對(duì)? 失戀要跳樓又怎么辦? 意思是超過(guò)他的認(rèn)知范圍,靠它自己解決不了了,就需要有更高權(quán)限,更高智慧的人介入進(jìn)來(lái),幫著解決,干擦屁股的事.

那么應(yīng)用程序就是那個(gè)小孩,內(nèi)核就是監(jiān)護(hù)人,有更高的權(quán)限,更高的智慧.而且監(jiān)護(hù)人還不止一個(gè),而是六個(gè),每個(gè)監(jiān)護(hù)人對(duì)應(yīng)解決一種情況,情況發(fā)生了就由它來(lái)接管這件事的處理,小朋友你就別管了哈,先把你關(guān)家里,處理好了外面安全了再把應(yīng)用程序放出來(lái)玩去.

這六個(gè)人處理問(wèn)題都自帶工具,有標(biāo)準(zhǔn)的解決方案,有自己獨(dú)立的辦公場(chǎng)所,辦公場(chǎng)所就是?？臻g(獨(dú)立的),標(biāo)準(zhǔn)解決方案就是私有代碼段,放在固定的位置.而自帶的工具就是SPSR_***,SP_***,LR_***寄存器組.詳見(jiàn)系列篇之工作模式篇,這里再簡(jiǎn)單回顧下有哪些工作模式,包括小孩自己(用戶(hù)模式)一共是七種模式.

七種工作模式

圖來(lái)源于ARM720T.pdf第43頁(yè),在ARM體系中,CPU工作在以下七種模式中:

用戶(hù)模式（usr）：該模式是用戶(hù)程序的工作模式，它運(yùn)行在操作系統(tǒng)的用戶(hù)態(tài)，它沒(méi)有權(quán)限去操作其它硬件資源，只能執(zhí)行處理自己的數(shù)據(jù)，也不能切換到其它模式下，要想訪(fǎng)問(wèn)硬件資源或切換到其它模式只能通過(guò)軟中斷或產(chǎn)生異常。

快速中斷模式（fiq）：快速中斷模式是相對(duì)一般中斷模式而言的，用來(lái)處理高優(yōu)先級(jí)中斷的模式,處理對(duì)時(shí)間要求比較緊急的中斷請(qǐng)求，主要用于高速數(shù)據(jù)傳輸及通道處理中。

普通中斷模式（irq）：一般中斷模式也叫普通中斷模式，用于處理一般的中斷請(qǐng)求，通常在硬件產(chǎn)生中斷信號(hào)之后自動(dòng)進(jìn)入該模式，該模式可以自由訪(fǎng)問(wèn)系統(tǒng)硬件資源。

管理模式（svc）：操作系統(tǒng)保護(hù)模式，CPU上電復(fù)位和當(dāng)應(yīng)用程序執(zhí)行 SVC 指令調(diào)用系統(tǒng)服務(wù)時(shí)也會(huì)進(jìn)入此模式,操作系統(tǒng)內(nèi)核的普通代碼通常工作在這個(gè)模式下。

終止模式（abt）：當(dāng)數(shù)據(jù)或指令預(yù)取終止時(shí)進(jìn)入該模式，中止模式用于支持虛擬內(nèi)存或存儲(chǔ)器保護(hù)，當(dāng)用戶(hù)程序訪(fǎng)問(wèn)非法地址，沒(méi)有權(quán)限讀取的內(nèi)存地址時(shí)，會(huì)進(jìn)入該模式，

系統(tǒng)模式（sys）：供操作系統(tǒng)使用的高特權(quán)用戶(hù)模式,與用戶(hù)模式類(lèi)似，但具有可以直接切換到其他模式等特權(quán),用戶(hù)模式與系統(tǒng)模式兩者使用相同的寄存器，都沒(méi)有SPSR（Saved Program Statement Register，已保存程序狀態(tài)寄存器），但系統(tǒng)模式比用戶(hù)模式有更高的權(quán)限，可以訪(fǎng)問(wèn)所有系統(tǒng)資源。

未定義模式（und）：未定義模式用于支持硬件協(xié)處理器的軟件仿真，CPU在指令的譯碼階段不能識(shí)別該指令操作時(shí)，會(huì)進(jìn)入未定義模式。

除用戶(hù)模式外，其余6種工作模式都屬于特權(quán)模式

特權(quán)模式中除了系統(tǒng)模式以外的其余5種模式稱(chēng)為異常模式

大多數(shù)程序運(yùn)行于用戶(hù)模式

進(jìn)入特權(quán)模式是為了處理中斷、異常、或者訪(fǎng)問(wèn)被保護(hù)的系統(tǒng)資源

硬件權(quán)限級(jí)別：系統(tǒng)模式 > 異常模式 > 用戶(hù)模式

快中斷(fiq)與慢中斷(irq)區(qū)別：快中斷處理時(shí)禁止中斷

每種模式都有自己獨(dú)立的入口和獨(dú)立的運(yùn)行?？臻g.系列篇之CPU篇已介紹過(guò)只要提供了入口函數(shù)和運(yùn)行空間,CPU就可以干活了.入口函數(shù)解決了指令來(lái)源問(wèn)題,運(yùn)行空間解決了指令的運(yùn)行場(chǎng)地問(wèn)題. 而且在多核情況下,每個(gè)CPU核的每種特權(quán)模式都有自己獨(dú)立的?？臻g.注意是特權(quán)模式下的?？臻g,用戶(hù)模式的?？臻g是由用戶(hù)(應(yīng)用)程序提供的.

官方概念

異常接管是操作系統(tǒng)對(duì)運(yùn)行期間發(fā)生的異常情況（芯片硬件異常）進(jìn)行處理的一系列動(dòng)作，例如打印異常發(fā)生時(shí)當(dāng)前函數(shù)的調(diào)用棧信息、CPU現(xiàn)場(chǎng)信息、任務(wù)的堆棧情況等。 異常接管作為一種調(diào)測(cè)手段，可以在系統(tǒng)發(fā)生異常時(shí)給用戶(hù)提供有用的異常信息，譬如異常類(lèi)型、發(fā)生異常時(shí)的系統(tǒng)狀態(tài)等，方便用戶(hù)定位分析問(wèn)題。

鴻蒙的異常接管，在系統(tǒng)發(fā)生異常時(shí)的處理動(dòng)作為：顯示異常發(fā)生時(shí)正在運(yùn)行的任務(wù)信息（包括任務(wù)名、任務(wù)號(hào)、堆棧大小等），以及CPU現(xiàn)場(chǎng)等信息。

進(jìn)入和退出異常方式

異常接管切換需要處理好兩件事:

一個(gè)是代碼要切到哪個(gè)位置,也就是要重置PC寄存器,每種異常模式下的切換方式如圖:

另一個(gè)是要恢復(fù)每種模式的狀態(tài),即CPSR(1個(gè))和SPSR(共5個(gè))的關(guān)系,對(duì)M[4:0]的修改,如圖:

以下是M[4:0]在每種模式下具體操作方式:

棧幀

每個(gè)函數(shù)都有自己的?？臻g，稱(chēng)為棧幀。調(diào)用函數(shù)時(shí)，會(huì)創(chuàng)建子函數(shù)的棧幀，同時(shí)將函數(shù)入?yún)ⅰ⒕植孔兞?、寄存器入棧。棧幀從高地址向低地址生長(zhǎng),也就是說(shuō)棧底是高地址,棧頂是底地址. 詳見(jiàn)系列篇之用棧方式篇

以ARM32 CPU架構(gòu)為例，每個(gè)棧幀中都會(huì)保存PC、LR、SP和FP寄存器的歷史值。 堆棧分析原理如下圖所示，實(shí)際堆棧信息根據(jù)不同CPU架構(gòu)有所差異，此處僅做示意。 圖中不同顏色的寄存器表示不同的函數(shù)?？梢钥吹胶瘮?shù)調(diào)用過(guò)程中，寄存器的保存。通過(guò)FP寄存器，棧回溯到異常函數(shù)的父函數(shù)，繼續(xù)按照規(guī)律對(duì)棧進(jìn)行解析，推出函數(shù)調(diào)用關(guān)系，方便用戶(hù)定位問(wèn)題。

解讀

LR寄存器（Link Register），鏈接寄存器，指向函數(shù)的返回地址。

R11：可以用作通用寄存器，在開(kāi)啟特定編譯選項(xiàng)時(shí)可以用作幀指針寄存器FP，用來(lái)實(shí)現(xiàn)?；厮莨δ?。 GNU編譯器（gcc）默認(rèn)將R11作為存儲(chǔ)變量的通用寄存器，因而默認(rèn)情況下無(wú)法使用FP的?；厮莨δ?。為支持調(diào)用棧解析功能，需要在編譯參數(shù)中添加-fno-omit-frame-pointer選項(xiàng)，提示編譯器將R11作為FP使用。

FP寄存器（Frame Point），幀指針寄存器，指向當(dāng)前函數(shù)的父函數(shù)的棧幀起始地址。利用該寄存器可以得到父函數(shù)的棧幀，從棧幀中獲取父函數(shù)的FP，就可以得到祖父函數(shù)的棧幀，以此類(lèi)推，可以追溯程序調(diào)用棧，得到函數(shù)間的調(diào)用關(guān)系。 當(dāng)系統(tǒng)發(fā)生異常時(shí)，系統(tǒng)打印異常函數(shù)的棧幀中保存的寄存器內(nèi)容，以及父函數(shù)、祖父函數(shù)的棧幀中的LR、FP寄存器內(nèi)容，用戶(hù)就可以據(jù)此追溯函數(shù)間的調(diào)用關(guān)系，定位異常原因。

六種異常模式實(shí)現(xiàn)代碼

/* Define exception type ID */		//ARM處理器一共有7種工作模式，除了用戶(hù)和系統(tǒng)模式其余都叫異常工作模式
#define OS_EXCEPT_RESET          0x00	//重置功能，例如：開(kāi)機(jī)就進(jìn)入CPSR_SVC_MODE模式
#define OS_EXCEPT_UNDEF_INSTR    0x01	//未定義的異常，就是others
#define OS_EXCEPT_SWI            0x02	//軟中斷
#define OS_EXCEPT_PREFETCH_ABORT 0x03	//預(yù)取異常(取指異常), 指令三步驟: 取指,譯碼,執(zhí)行, 
#define OS_EXCEPT_DATA_ABORT     0x04	//數(shù)據(jù)異常
#define OS_EXCEPT_FIQ            0x05	//快中斷異常
#define OS_EXCEPT_ADDR_ABORT     0x06	//地址異常
#define OS_EXCEPT_IRQ            0x07	//普通中斷異常

地址異常處理(Address abort)

@ Description: Address abort exception handler
_osExceptAddrAbortHdl: @地址異常處理
    SUB     LR, LR, #8                                       @ LR offset to return from this exception: -8.
    STMFD   SP, {R0-R7}                                      @ Push working registers, but don`t change SP.

    MOV     R0, #OS_EXCEPT_ADDR_ABORT                        @ Set exception ID to OS_EXCEPT_ADDR_ABORT.

    B       _osExceptDispatch                                @跳到異常分發(fā)統(tǒng)一處理

快中斷處理(fiq)

@ Description: Fast interrupt request exception handler
_osExceptFiqHdl: @快中斷異常處理
    SUB     LR, LR, #4                                       @ LR offset to return from this exception: -4.
    STMFD   SP, {R0-R7}                                      @ Push working registers.

    MOV     R0, #OS_EXCEPT_FIQ                               @ Set exception ID to OS_EXCEPT_FIQ.

    B       _osExceptDispatch                                @ Branch to global exception handler.

解讀

快中斷處理時(shí)需禁用普通中斷

取指異常(Prefectch abort)

@ Description: Prefectch abort exception handler
_osExceptPrefetchAbortHdl:
#ifdef LOSCFG_GDB
#if __LINUX_ARM_ARCH__ >= 7
    GDB_HANDLE OsPrefetchAbortExcHandleEntry
#endif
#else
    SUB     LR, LR, #4                                       @ LR offset to return from this exception: -4.
    STMFD   SP, {R0-R7}                                      @ Push working registers, but don`t change SP.
    MOV     R5, LR
    MRS     R1, SPSR

    MOV     R0, #OS_EXCEPT_PREFETCH_ABORT                    @ Set exception ID to OS_EXCEPT_PREFETCH_ABORT.

    AND     R4, R1, #CPSR_MASK_MODE                          @ Interrupted mode
    CMP     R4, #CPSR_USER_MODE                              @ User mode
    BEQ     _osExcPageFault                                   @ Branch if user mode

_osKernelExceptPrefetchAbortHdl:
    MOV     LR, R5
    B       _osExceptDispatch                                @ Branch to global exception handler.
#endif

數(shù)據(jù)訪(fǎng)問(wèn)異常(Data abort)

@ Description: Data abort exception handler
_osExceptDataAbortHdl: @數(shù)據(jù)異常處理,缺頁(yè)就屬于數(shù)據(jù)異常
#ifdef LOSCFG_GDB
#if __LINUX_ARM_ARCH__ >= 7
    GDB_HANDLE OsDataAbortExcHandleEntry
#endif
#else
    SUB     LR, LR, #8                                       @ LR offset to return from this exception: -8.
    STMFD   SP, {R0-R7}                                      @ Push working registers, but don`t change SP.
    MOV     R5, LR
    MRS     R1, SPSR

    MOV     R0, #OS_EXCEPT_DATA_ABORT                        @ Set exception ID to OS_EXCEPT_DATA_ABORT.

    B     _osExcPageFault   @跳到缺頁(yè)異常處理
#endif

軟中斷處理(swi)

@ Description: Software interrupt exception handler
_osExceptSwiHdl: @軟中斷異常處理
    SUB     SP, SP, #(4 * 16)	@先申請(qǐng)16個(gè)?？臻g用于處理本次軟中斷
    STMIA   SP, {R0-R12}		@保存R0-R12寄存器值
    MRS     R3, SPSR			@讀取本模式下的SPSR值
    MOV     R4, LR				@保存回跳寄存器LR

    AND     R1, R3, #CPSR_MASK_MODE                          @ Interrupted mode 獲取中斷模式
    CMP     R1, #CPSR_USER_MODE                              @ User mode	是否為用戶(hù)模式
    BNE     OsKernelSVCHandler                               @ Branch if not user mode 非用戶(hù)模式下跳轉(zhuǎn)
	@ 當(dāng)為用戶(hù)模式時(shí),獲取SP和LR寄出去值
    @ we enter from user mode, we need get the values of  USER mode r13(sp) and r14(lr).
    @ stmia with ^ will return the user mode registers (provided that r15 is not in the register list).
    MOV     R0, SP											 @獲取SP值,R0將作為OsArmA32SyscallHandle的參數(shù)
    STMFD   SP!, {R3}                                        @ Save the CPSR 入棧保存CPSR值
    ADD     R3, SP, #(4 * 17)                                @ Offset to pc/cpsr storage 跳到PC/CPSR存儲(chǔ)位置
    STMFD   R3!, {R4}                                        @ Save the CPSR and r15(pc) 保存LR寄存器
    STMFD   R3, {R13, R14}^                                  @ Save user mode r13(sp) and r14(lr) 保存用戶(hù)模式下的SP和LR寄存器
    SUB     SP, SP, #4
    PUSH_FPU_REGS R1	@保存中斷模式(用戶(hù)模式模式)											

    MOV     FP, #0                                           @ Init frame pointer
    CPSIE   I	@開(kāi)中斷,表明在系統(tǒng)調(diào)用期間可響應(yīng)中斷
    BLX     OsArmA32SyscallHandle	/*交給C語(yǔ)言處理系統(tǒng)調(diào)用*/
    CPSID   I	@執(zhí)行后續(xù)指令前必須先關(guān)中斷

    POP_FPU_REGS R1											 @彈出FP值給R1
    ADD     SP, SP,#4										 @ 定位到保存舊SPSR值的位置
    LDMFD   SP!, {R3}                                        @ Fetch the return SPSR 彈出舊SPSR值
    MSR     SPSR_cxsf, R3                                    @ Set the return mode SPSR 恢復(fù)該模式下的SPSR值

    @ we are leaving to user mode, we need to restore the values of USER mode r13(sp) and r14(lr).
    @ ldmia with ^ will return the user mode registers (provided that r15 is not in the register list)

    LDMFD   SP!, {R0-R12}									 @恢復(fù)R0-R12寄存器
    LDMFD   SP, {R13, R14}^                                  @ Restore user mode R13/R14 恢復(fù)用戶(hù)模式的R13/R14寄存器
    ADD     SP, SP, #(2 * 4)								 @定位到保存舊PC值的位置
    LDMFD   SP!, {PC}^                                       @ Return to user 切回用戶(hù)模式運(yùn)行

普通中斷處理(irq)

OsIrqHandler:	@硬中斷處理,此時(shí)已切換到硬中斷棧
    SUB     LR, LR, #4
    /* push r0-r3 to irq stack */
    STMFD   SP, {R0-R3}		@r0-r3寄存器入 irq 棧
    SUB     R0, SP, #(4 * 4)@r0 = sp - 16
    MRS     R1, SPSR		@獲取程序狀態(tài)控制寄存器
    MOV     R2, LR			@r2=lr

    /* disable irq, switch to svc mode */@超級(jí)用戶(hù)模式(SVC 模式)，主要用于 SWI(軟件中斷)和 OS(操作系統(tǒng))。
    CPSID   i, #0x13				@切換到SVC模式,此處一切換,后續(xù)指令將入SVC的棧
									@CPSID i為關(guān)中斷指令,對(duì)應(yīng)的是CPSIE
    /* push spsr and pc in svc stack */
    STMFD   SP!, {R1, R2} @實(shí)際是將 SPSR,和LR入棧,入棧順序?yàn)?R1,R2,SP自增
    STMFD   SP, {LR}	  @LR再入棧,SP不自增

    AND     R3, R1, #CPSR_MASK_MODE	@獲取CPU的運(yùn)行模式
    CMP     R3, #CPSR_USER_MODE		@中斷是否發(fā)生在用戶(hù)模式
    BNE     OsIrqFromKernel			@中斷不發(fā)生在用戶(hù)模式下則跳轉(zhuǎn)到OsIrqFromKernel

    /* push user sp, lr in svc stack */
    STMFD   SP, {R13, R14}^ 		@sp和LR入svc棧

解讀

普通中斷處理時(shí)可以響應(yīng)快中斷

未定義異常處理(undef)

@ Description: Undefined instruction exception handler
_osExceptUndefInstrHdl:@出現(xiàn)未定義的指令處理
#ifdef LOSCFG_GDB
    GDB_HANDLE OsUndefIncExcHandleEntry
#else
                                                              @ LR offset to return from this exception:  0.
    STMFD   SP, {R0-R7}                                       @ Push working registers, but don`t change SP.

    MOV     R0, #OS_EXCEPT_UNDEF_INSTR                        @ Set exception ID to OS_EXCEPT_UNDEF_INSTR.

    B       _osExceptDispatch                                 @ Branch to global exception handler.

#endif

異常分發(fā)統(tǒng)一處理

_osExceptDispatch: @異常模式統(tǒng)一分發(fā)處理
    MRS     R2, SPSR                                         @ Save CPSR before exception.
    MOV     R1, LR                                           @ Save PC before exception.
    SUB     R3, SP, #(8 * 4)                                 @ Save the start address of working registers.

    MSR     CPSR_c, #(CPSR_INT_DISABLE | CPSR_SVC_MODE)      @ Switch to SVC mode, and disable all interrupts
    MOV     R5, SP
    EXC_SP_SET __exc_stack_top, OS_EXC_STACK_SIZE, R6, R7

    STMFD   SP!, {R1}                                        @ Push Exception PC
    STMFD   SP!, {LR}                                        @ Push SVC LR
    STMFD   SP!, {R5}                                        @ Push SVC SP
    STMFD   SP!, {R8-R12}                                    @ Push original R12-R8,
    LDMFD   R3!, {R4-R11}                                    @ Move original R7-R0 from exception stack to original stack.
    STMFD   SP!, {R4-R11}
    STMFD   SP!, {R2}                                        @ Push task`s CPSR (i.e. exception SPSR).

    CMP     R0, #OS_EXCEPT_DATA_ABORT 		@是數(shù)據(jù)異常嗎?
    BNE     1f 								@不是跳到 錨點(diǎn)1處
    MRC     P15, 0, R8, C6, C0, 0 			@R8=C6(內(nèi)存失效的地址) 0(訪(fǎng)問(wèn)數(shù)據(jù)失效)
    MRC     P15, 0, R9, C5, C0, 0 			@R9=C5(內(nèi)存失效的狀態(tài)) 0(無(wú)效整個(gè)指令cache)
    B       3f 								@跳到錨點(diǎn)3處執(zhí)行
1:  CMP     R0, #OS_EXCEPT_PREFETCH_ABORT 	@是預(yù)取異常嗎?
    BNE     2f 								@不是跳到 錨點(diǎn)2處
    MRC     P15, 0, R8, C6, C0, 2 			@R8=C6(內(nèi)存失效的地址) 2(訪(fǎng)問(wèn)指令失效)
    MRC     P15, 0, R9, C5, C0, 1 			@R9=C5(內(nèi)存失效的狀態(tài)) 1(虛擬地址)
    B       3f 								@跳到錨點(diǎn)3處執(zhí)行
2:  MOV     R8, #0
    MOV     R9, #0

3:  AND     R2, R2, #CPSR_MASK_MODE 
    CMP     R2, #CPSR_USER_MODE                              @ User mode
    BNE     4f @不是用戶(hù)模式
    STMFD   SP, {R13, R14}^                                  @ save user mode sp and lr
4:
    SUB     SP, SP, #(4 * 2) @sp=sp-(4*2)

非常重要的ARM37個(gè)寄存器

結(jié)尾

以上為異常接管對(duì)應(yīng)的代碼處理,具體每種異常發(fā)生的場(chǎng)景和代碼細(xì)節(jié)處理

編輯：hfy