電子發(fā)燒友App
點鈔機外接顯示屏的匯編程如下：
;* ====================================================== *
;* 華信單片機工作室 盧先生sktlch@126.com
;* 整理驗證日期： 2002/09/23
;----------------------------------------------------------
;* 標題：點鈔機外接顯示屏，程序名：File = WJD961_4.ASM
;* 描述： 采用AT89C2051芯片，晶振頻率：11.0592MHz。
;* 初始狀態(tài)數(shù)碼管個位顯示“0”，最大計數(shù)范圍： 999。
;* =======================================================*
LED1 BIT P3.5 ;百位（定義數(shù)碼管公共端）
LED2 BIT P3.4 ;十位
LED3 BIT P3.7 ;個位
JSQ0 DATA 50H ;脈沖計數(shù)單元高字節(jié)
JSQ1 DATA 51H ;脈沖計數(shù)單元低字節(jié)
LED01 DATA 3AH ;顯示段碼緩存器（百位）
LED02 DATA 3BH ;十位
LED03 DATA 3CH ;個位
R31 DATA 1FH
;* =======================================================*
ORG 0000H
AJMP START ;復位轉(zhuǎn)主程序
ORG 0003H ;INT0的入口地址
AJMP INT0_P32
;* ------------------------------------------------------ *
; 主程序0030H單元開始
;* ------------------------------------------------------ *
ORG 0030H ;跳過中斷向量區(qū)
START： MOV R0，#7FH
CLR A
DEL1： MOV @R0，A ;預使用單元清0
DJNZ R0，DEL1
MAIN： MOV SP，#60H ;60H為棧頂位置初值
SETB IT0 ;置INT0為邊沿觸發(fā)方式
MOV IP，#00000001B ;置INT0為高優(yōu)先級中斷
MOV IE，#10000001B ;INT0開中
MOV JSQ0，#0 ;計數(shù)單元清0
MOV JSQ1，#0
CLR P1.0 ;注意在軟件模擬調(diào)試時，P1.0由于沒有接外部上拉電阻，
;拉低后就無法拉高。為了調(diào)試方便可選取89C51進調(diào)試
;*--------------------------------------------------------*
DIR0_0:JB P1.0，DIR0_01 ;當點鈔機已復位，但未放入紙幣，所以未中斷
MOV R31，#28
ACALL DELAY2 ;延時1ms，去抖動
JB P1.0，DIR0_01
SETB P1.0
MOV JSQ0，#0 ;復位信正確，計數(shù)單元清0
MOV JSQ1，#0
ACALL HB2 ;將16進制數(shù)轉(zhuǎn)換為BCD碼
ACALL THIF0 ;調(diào)用轉(zhuǎn)換顯示值子程序
DIR0_01：
MOV A，LED01 ;當十位，百位數(shù)=0時，將其屏蔽
CJNE A，#81H，DIR0_02
MOV LED01，#0FFH
MOV A，LED02
CJNE A，#81H，DIR0_02
MOV LED02，#0FFH
DIR0_02：
SETB LED1 ;LED1位顯示停
MOV P1，LED03 ;讀個位段碼
CLR LED3 ;LED1個位顯示
MOV R31，#42
ACALL DELAY2 ;延時2ms
SETB LED3 ;LED1位顯示停
MOV P1，LED02 ;讀十位段碼
CLR LED2 ;LED2十位顯示
MOV R31，#42
ACALL DELAY2
SETB LED2 ;LED2十位顯示停
MOV P1，LED01 ;讀百位段碼
CLR LED1 ;LED1百位顯示
MOV R31，#42
ACALL DELAY2
AJMP DIR0_0 ;不斷循環(huán)顯示，并等待中斷
;* =======================================================*
;計數(shù)復位時，點鈔機主程序會先給出一個復位信號，并持續(xù)一段時間，
;接著給出計數(shù)脈沖
INT0_P32：
PUSH ACC ;保護現(xiàn)場
PUSH DPH
PUSH DPL
JB P1.0，INT0_01 ;當點鈔機
MOV R31，#28
ACALL DELAY2 ;延時1ms，去抖動
JB P1.0，INT0_01
SETB P1.0 ;清除復位信號
MOV JSQ0，#0 ;復位信正確，計數(shù)單元清0
MOV JSQ1，#0
INT0_01：
MOV A，JSQ1 ;低字節(jié)計數(shù)單元加1
INC A
MOV JSQ1，A
JNZ INT0_02
INC JSQ0 ;當有進位時，高字節(jié)單元加1
INT0_02：
ACALL HB2 ;將16進制數(shù)轉(zhuǎn)換為BCD碼
ACALL THIF0 ;調(diào)用轉(zhuǎn)換顯示值子程序
POP DPL ;恢復現(xiàn)場
POP DPH
POP ACC
RETI ;中斷返回
;* =======================================================*
;* 雙字節(jié)十六進制整數(shù)轉(zhuǎn)換成雙字節(jié)ＢＣＤ碼整數(shù)
;入口條件：待轉(zhuǎn)換的雙字節(jié)十六進制整數(shù)在R6、R7中。
;出口信息：轉(zhuǎn)換后的三字節(jié)ＢＣＤ碼整數(shù)在R3、R4、R5中。
;影響資源：PSW、A、R2～R7堆棧需求： ２字節(jié)
;* =======================================================*
HB2：
MOV R6，JSQ0 ;高字節(jié)單元送入R6
MOV R7，JSQ1 ;低字節(jié)單元送入R7
CLR A ;BCD碼初始化
MOV R3，A
MOV R4，A
MOV R5，A
MOV R2，#10H ;轉(zhuǎn)換雙字節(jié)十六進制整數(shù)
HB3：
MOV A，R7 ;從高端移出待轉(zhuǎn)換數(shù)的一位到CY中
RLC A
MOV R7，A
MOV A，R6
RLC A
MOV R6，A
MOV A，R5 ;BCD碼帶進位自身相加，相當于乘2
DA A ;十進制調(diào)整
MOV R5，A
MOV A，R4
ADDC A，R4
DA A
MOV R4，A
MOV A，R3
ADDC A，R3
MOV R3，A ;雙字節(jié)十六進制數(shù)的萬位數(shù)不超過6，不用調(diào)整
DJNZ R2，HB3 ;處理完16bit
RET
;* =======================================================*
;* 將BCD碼解壓后，轉(zhuǎn)換為十進制顯示符
;* =======================================================*
THIF0： ;將壓縮BCD碼解壓（因最大數(shù)為999，所以［R3］=0）
MOV A，R5 ;取數(shù)據(jù)
ANL A，#0FH ;屏蔽高4位，取出低4位
MOV 32H，A ;存?zhèn)€位
MOV A，R5
SWAP A ;交換
ANL A，#0FH
MOV 31H，A ;存十位
MOV A，R4 ;取數(shù)據(jù)
ANL A，#0FH ;屏蔽高4位，取出低4位
MOV 30H，A ;存百位
;* 將BCD轉(zhuǎn)換為十進制顯示符
MOV DPTR，#TABD ;置數(shù)碼表首址
MOV R0，#30H ;置顯示數(shù)首址
MOV R1，#LED01 ;置字段碼暫存器首址
MOV R2，#03H ;置循環(huán)數(shù)
THIF1：
MOV A，@R0 ;取顯示數(shù)
MOVC A，@A+DPTR ;讀字段碼
MOV @R1，A ;存字段碼
INC R0 ;修改顯示數(shù)地址
INC R1 ;修改字段碼暫存器地址
DJNZ R2，THIF1 ;判斷循環(huán)是否結(jié)束
RET
TABD：
DB 81H，0EDH，43H，49H，2DH，19H ;共陽字段表，0～5顯示符
DB 11H，0CDH，01H，09H ;6～9顯示符
;* =======================================================*
;* 延時子程序
DELAY2：
L2： PUSH R31
L3： DJNZ R31，L3
POP R31
DJNZ R31，L2
RET
END
;* =======================================================*
工商網(wǎng)監(jiān)
評論