在OLED屏幕上獲取實(shí)時(shí)心電圖

描述

前段時(shí)間，我發(fā)布了幾個項(xiàng)目，演示了如何從 uECG 設(shè)備獲取數(shù)據(jù) - 但他們有很多混亂的代碼，并且仍然只使用其中的基本數(shù)據(jù)。所以最后我寫了一個 Arduino 庫，使這種方式更簡單，更可靠，這里是：https ://github.com/ultimaterobotics/uECG_library （請注意，您還需要從庫管理器安裝 RF24 庫，如果您想要在這個項(xiàng)目中顯示 OLED 上的數(shù)據(jù) - 也是 Adafruit 的 SSD1306 庫）。

1. 原理圖

原理圖與使用 nRF24 模塊和 OLED 的任何其他項(xiàng)目相同：nRF24 連接到 Arduino 的 SPI 總線（D13、D12、D11）和模塊 CS 和 CE 線的兩個任意引腳 - 為了方便起見，我選擇了 D10 和 D9。唯一重要的一點(diǎn)：nRF24模塊必須接3.3V線，不能接5V！在 3.3V 和 GND 之間添加 1uF 或 10uF 電容器也有很大幫助——那些 nRF24 模塊需要穩(wěn)定的電壓，而 Arduino 不能總是在其 3.3V 線路上提供，電容器有助于實(shí)現(xiàn)這一點(diǎn)。

OLED 通過 I2C - SDA 連接到 A4，SCL 連接到 A5，并由 5V 線路供電。就我而言，OLED 模塊具有用于 I2C 協(xié)議的內(nèi)置電阻器。如果您的模塊沒有它們 - 您需要在 SDA 到 3.3V 和從 SCL 到 3.3V 之間添加 4.7k 電阻，盡管我最近看到的大多數(shù)模塊已經(jīng)有了它們。

您可以在下面看到示意圖，這是組裝項(xiàng)目的照片：

?

2.代碼

uECG 庫需要幾行代碼才能正常運(yùn)行，即：

在 setup() 中，您需要調(diào)用 uECG.begin(pin_cs, pin_ce) - 您需要告訴它哪些引腳號用于 nRF24 CS 和 CE 線路，它將打開模塊并在內(nèi)部將其置于正確的模式。

在 loop() 中，您需要盡可能頻繁地調(diào)用 uECG.run()：uECG 設(shè)備會發(fā)送大量數(shù)據(jù) - 每幾毫秒一個數(shù)據(jù)包 - 如果您在下一次之前不調(diào)用 uECG.run()數(shù)據(jù)包到達(dá)，其數(shù)據(jù)將丟失。這意味著永遠(yuǎn)不要在循環(huán)內(nèi)調(diào)用 delay() 函數(shù)，并為需要計(jì)時(shí)的任務(wù)使用 millis() （我在庫示例中添加了一個示例）。

該項(xiàng)目代碼在庫中作為示例提供，也附在下面（如果它看起來太復(fù)雜 - 請記住，這里 95% 的代碼專用于優(yōu)化顯示繪圖，用于簡單地將值打印到串行監(jiān)視器中只需要幾行）：

#include 
#include 
#include 

#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 64 // OLED display height, in pixels

// Declaration for an SSD1306 display connected to I2C (SDA, SCL pins)
#define OLED_RESET     -1 // Reset pin # (or -1 if sharing Arduino reset pin)
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

int rf_cen = 9; //nRF24 chip enable pin
int rf_cs = 10; //nRF24 CS pin

void setup() {
  Serial.begin(115200); //serial output - very useful for debugging
  while(!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) { // Address 0x3D for 128x64
    Serial.println(F("SSD1306 allocation failed"));
  }
  display.display();
  delay(100);
  uECG.begin(rf_cs, rf_cen);
  delay(100);

  // Clear the buffer
  display.clearDisplay();
  display.setTextSize(1);      // Normal 1:1 pixel scale
  display.setTextColor(WHITE); // Draw white text
  display.cp437(true);         // Use full 256 char 'Code Page 437' font
  display.display();
  delay(100);
  Serial.println("after display");
}

uint32_t prev_data_count = 0;
uint32_t prev_displ = 0;

uint8_t ecg_screen[128];
int ecg_screen_len = 128;
float ecg_avg = 0;
float ecg_max = 1;
float ecg_min = -1;
int ecg_size = 40;

int displ_phase = 0;

void loop() 
{
  uECG.run();
  uint32_t data_count = uECG.getDataCount();
  int new_data = data_count - prev_data_count;
  prev_data_count = data_count;
  if(new_data > 0)
  {
    uint32_t ms = millis();
    int16_t ecg_data[8];
    uECG.getECG(ecg_data, new_data);
    for(int x = 0; x < new_data; x++)
      Serial.println(ecg_data[x]);
      
    for(int x = new_data; x < ecg_screen_len; x++)
      ecg_screen[x-new_data] = ecg_screen[x];
    for(int x = 0; x < new_data; x++)
    {
      ecg_avg *= 0.99;
      ecg_avg += 0.01*ecg_data[x];
      ecg_max = ecg_max*0.995 + ecg_avg*0.005;
      ecg_min = ecg_min*0.995 + ecg_avg*0.005;
      if(ecg_data[x] > ecg_max) ecg_max = ecg_data[x];
      if(ecg_data[x] < ecg_min) ecg_min = ecg_data[x];
      int ecg_y = 63-ecg_size*(ecg_data[x] - ecg_min) / (ecg_max - ecg_min + 1);
      ecg_screen[ecg_screen_len-1-new_data+x] = ecg_y;
    }

    if(ms - prev_displ > 30)
    {
      prev_displ = ms;
      if(displ_phase == 0)
      {
        display.clearDisplay();
        display.setCursor(0, 0);
        display.print("BPM: ");
        display.println(uECG.getBPM());
        display.print(" RR: ");
        display.println(uECG.getLastRR());
        display.print("steps: ");
        display.print(uECG.getSteps());
        int batt_mv = uECG.getBattery();
        int batt_perc = (batt_mv - 3300)/8;
        if(batt_perc < 0) batt_perc = 0;
        if(batt_perc > 100) batt_perc = 100;
        display.drawLine(110, 0, 127, 0, WHITE);
        display.drawLine(110, 10, 127, 10, WHITE);
        display.drawLine(110, 0, 110, 10, WHITE);
        display.drawLine(127, 0, 127, 10, WHITE);
        int bat_len = batt_perc / 6;
        for(int x = 1; x < 10; x++)
          display.drawLine(110, x, 110+bat_len, x, WHITE);
      }
      if(displ_phase == 1) 
      {
        for(int x = 1; x < ecg_screen_len/2; x++)
          display.drawLine(x-1, ecg_screen[x-1], x, ecg_screen[x], WHITE);
      }      
      if(displ_phase == 2) 
      {
        for(int x = ecg_screen_len/2; x < ecg_screen_len-1; x++)
          display.drawLine(x-1, ecg_screen[x-1], x, ecg_screen[x], WHITE);
      }
      if(displ_phase == 3) 
        display.display();
      displ_phase++;
      if(displ_phase > 3) displ_phase = 0;
    }
  }
}

3.處理數(shù)據(jù)

板載執(zhí)行大量處理，您可以獲得設(shè)備計(jì)算的各種統(tǒng)計(jì)數(shù)據(jù)：BPM、GSR、最后 RR 間隔、HRV 參數(shù)和 16 個 HRV 箱（第一個箱表示變化 <1% 的節(jié)拍量，第二個箱 - 1% 到 2% 之間的變化等），步行的步數(shù)，加速度計(jì)讀數(shù)（雖然刷新率很低，所以它只適用于姿勢估計(jì)）。

但是您也可以獲得原始 ECG 讀數(shù) - 數(shù)據(jù)流并不完美，有時(shí)會丟失一些數(shù)據(jù)包，但您仍然可以獲得可用的東西：

?

好吧，就是這樣 - 如果你讓這個設(shè)備在角落里收集灰塵，現(xiàn)在它實(shí)際上可以正常工作了：）