高精度等間距二維三維PSO輸出教程

上節(jié)課程我們講述了多種PSO模式原理和使用方法，本節(jié)課程我們主要講解一下如何使用PSO功能實(shí)現(xiàn)高精度等間距輸出。

一、硬件說(shuō)明

硬件選型的首要要求是支持PSO功能，再分析PSO的應(yīng)用場(chǎng)合和軸數(shù)等選擇具體的型號(hào)。本例以ZMC460N雙總線運(yùn)動(dòng)控制器為例展開(kāi)介紹。

PSO功能用于控制激光或點(diǎn)膠閥的高速開(kāi)/關(guān)，直線插補(bǔ)和平面圓弧插補(bǔ)功能用于完成加工軌跡，連續(xù)插補(bǔ)功能用于讓多段插補(bǔ)的速度連續(xù)，提高加工的效率。

ZMC460N雙總線控制器

ZMC460N雙總線控制器是正運(yùn)動(dòng)技術(shù)推出的新一代網(wǎng)絡(luò)60軸運(yùn)動(dòng)控制器（支持EtherCAT總線軸+RTEX總線軸+脈沖軸混合使用），自帶六個(gè)脈沖軸接口（包含差分脈沖輸出和差分編碼器輸入），通用輸出口支持配置為單端脈沖輸出，通用輸入口支持配置成單端編碼器輸入。脈沖輸出頻率最大可達(dá)10MHZ，EtherCAT總線的通訊周期最快可達(dá)250微秒。

支持12路PSO輸出，輸出口獨(dú)立，支持12路同時(shí)輸出，每個(gè)系統(tǒng)周期可比較輸出多次，應(yīng)用場(chǎng)景更為豐富。

PSO功能主要通過(guò)“HW_PSWITCH2”硬件位置比較輸出指令和“HW_TIMER”硬件定時(shí)指令實(shí)現(xiàn)，下面來(lái)講解一下這兩個(gè)指令的詳細(xì)用法。

二、指令說(shuō)明

1.HW_PSWITCH2

案例將會(huì)用到HW_PSWITCH2以下幾個(gè)模式，指令語(yǔ)法說(shuō)明如下：

（1）Mode=6：矢量比較方式，周期模式，與HW_TIMER一起使用

HW_PSWITCH2(6,opnum,opstate,vectstart,repes,cycledis)

mode：6-啟動(dòng)比較器

opnum：對(duì)應(yīng)的輸出口

opstate：第一個(gè)比較點(diǎn)的輸出狀態(tài)

vectstart：比較點(diǎn)VECTOR_MOVED當(dāng)前運(yùn)動(dòng)距離

repes：重復(fù)周期，一個(gè)周期只比較一次

cycledis：周期距離，每隔這個(gè)距離輸出一次

⊙ 說(shuō)明： 此模式無(wú)需TABLE，坐標(biāo)均參考矢量坐標(biāo)，從vectstart的位置開(kāi)始比較，每隔cycledis距離觸發(fā)一次比較，重復(fù)比較的周期為repes，每次觸發(fā)比較信號(hào)后，保持信號(hào)的脈沖寬度由HW_TIMER指令設(shè)置。

HW_TIMER可以控制到達(dá)一個(gè)觸發(fā)點(diǎn)控制OP反轉(zhuǎn)多次，HW_TIMER周期走完等待下一周期的觸發(fā)。

（2）Mode=7：矢量比較方式，采用TABLE，與HW_TIMER一起使用

HW_PSWITCH2(7,opnum,opstate,tablestart,tableend [,optimeus,optimes,cyctimeus])

mode：7-啟動(dòng)比較器，opstate不翻轉(zhuǎn)，方便與HW_TIMER配合使用

opnum：對(duì)應(yīng)的輸出口

opstate：第一個(gè)比較點(diǎn)的輸出狀態(tài)

tablestart：第一個(gè)比較點(diǎn)VECTOR_MOVED坐標(biāo)所在TABLE編號(hào)

tableend：最后一 個(gè)比較點(diǎn)VECTOR_MOVED坐標(biāo)所在TABLE編號(hào)

[以下參數(shù)和HW_TIMER二選一，HW_TIMER單獨(dú)寫(xiě)可以動(dòng)態(tài)調(diào)整參數(shù)]

optimeus：動(dòng)態(tài)調(diào)整HW_TIMER的有效時(shí)間

optimes：動(dòng)態(tài)調(diào)整HW_TIMER的觸發(fā)脈沖數(shù)，0-不輸出

cyctimeus：動(dòng)態(tài)調(diào)整HW_TIMER的脈沖周期時(shí)間

⊙ 說(shuō)明： 比較點(diǎn)寫(xiě)在TABLE中，坐標(biāo)均參考矢量坐標(biāo)，每到達(dá)一個(gè)TABLE比較矢量位置觸發(fā)OP，此時(shí)OP的脈沖寬度和每次觸發(fā)的比較次數(shù)由HW_TIMER控制；到達(dá)下一個(gè)TABLE位置，OP再次觸發(fā)。

2.HW_TIMER

硬件定時(shí)器，用于硬件比較輸出后一段時(shí)間后還原電平。HW_TIMER只有1個(gè)，每次調(diào)用會(huì)強(qiáng)制停止之前的調(diào)用。

不使用或比較完成時(shí)使用HW_TIMER(0)關(guān)閉。

HW_TIMER(mode,cyclonetime,optime,reptimes,opstate,opnum )

mode：0停止，2-啟動(dòng)

cyclonetime：周期時(shí)間，us單位

optime：有效時(shí)間，us單位

reptimes：重復(fù)次數(shù)，啟動(dòng)模式，reptimes =0時(shí)，軟關(guān)閉HW_TIMER，原來(lái)的脈沖沒(méi)有完成的，會(huì)繼續(xù)輸出完成

opstate：輸出缺省狀態(tài)，輸出口變?yōu)榉谴藸顟B(tài)后開(kāi)始計(jì)時(shí)

opnum：輸出口編號(hào)，必須能硬件比較輸出的口

⊙ 說(shuō)明： 參數(shù)設(shè)置可參考下方示意圖，此指令的效果是固定時(shí)間周期輸出，設(shè)置每個(gè)周期的有效輸出的時(shí)間和重復(fù)輸出的次數(shù)。

⊙使用HW_TIMER硬件定時(shí)無(wú)法仿真，只能在控制器平臺(tái)運(yùn)行。

三、二維等間距PSO輸出

等距比較輸出模式，不管運(yùn)動(dòng)速度和運(yùn)動(dòng)軌跡如何變化，始終固定距離輸出脈沖，使得輸出在空間上分布是均勻的，示意圖如下。

上節(jié)描述的模式中，有幾種模式都能實(shí)現(xiàn)XY平面的等距輸出，例如現(xiàn)有一段上左圖所示的軌跡，采用直線+圓弧+直線組成，每間隔10個(gè)距離比較輸出一次，一共比較12次，等間距輸出的方法參見(jiàn)下方例程的說(shuō)明。

例程：采用mode=6，矢量比較模式，結(jié)合HW_TIMER硬件定時(shí)，采用兩軸的合成矢量位置作為比較的參考坐標(biāo)位置，實(shí)現(xiàn)上方示意圖的效果，使用方便，無(wú)需計(jì)算位置坐標(biāo)，精度高。

RAPIDSTOP(2)
WAIT IDLE(0)
WAIT IDLE(1)
'基礎(chǔ)軸參數(shù)設(shè)置
BASE(0,1) '選擇XY軸
'ATYPE=4,4 '1-脈沖軸類(lèi)型，比較DPOS；4-帶編碼器反饋軸類(lèi)型，比較編碼器的反饋位置MPOS
UNITS=100,100
SPEED=100,100
ACCEL=1000,1000
DECEL=1000,1000
MERGE=ON,ON
SRAMP=50,50 's曲線速度平滑
OP(0,OFF)
'將當(dāng)前位置設(shè)置為0,0
DPOS=0,0
MPOS=0,0
DIM WidthTime,Interval,StartPos,EndPos
WidthTime = 20000 '脈沖寬度20000us
Interval = 10 '脈沖間隔
StartPos = 10 '觸發(fā)起始位置
EndPos = 130 '結(jié)束位置
FORCE_SPEED=60 'SP速度
MOVEABS(0) '運(yùn)動(dòng)到0位
WAIT IDLE
VECTOR_MOVED = 0 '插補(bǔ)矢量距離清0
DIM iTime
iTime =ABS(EndPos - StartPos) \ Interval '計(jì)算比較次數(shù)
TRACE StartPos,iTime,Interval,WidthTime
HW_PSWITCH2(2) '清空HW比較緩沖區(qū)
HW_PSWITCH2(6,0,ON,StartPos,iTime,Interval) '從StrartPos觸發(fā)比較間隔Interval比較iTime次
HW_TIMER(2,WidthTime+100,WidthTime,1,OFF,0) '輸出觸發(fā)變成ON后，打開(kāi)WidthTime us后關(guān)閉輸出
DELAY(10)
TRIGGER '啟動(dòng)示波器
MOVEABS(50,0) '開(kāi)始運(yùn)動(dòng)
MOVECIRCABSSP(75,25,50,25,0)
MOVEABS(75,75)
WAIT IDLE '等待運(yùn)動(dòng)停止
HW_PSWITCH2(2) '清空HW比較緩沖區(qū)
END

示波器采樣波形如下：采樣5個(gè)通道的波形，依次為軸0的目標(biāo)位置，軸1的目標(biāo)位置，輸出口0，軸0和軸1插補(bǔ)的矢量合成位置，軸0和軸1插補(bǔ)的運(yùn)行速度。

每間隔10個(gè)單位距離比較一次，一共比較12次，由HW_TIMER可精準(zhǔn)控制輸出脈沖的寬度，輸出頻率更快，整體精度更高。

XYZ模式下的比較輸出波形：

綜上所述，等距比較場(chǎng)合，使用模式6較為方便，只需要得出比較的距離和OP輸出的時(shí)間即可，模式6可用于單軸和多軸插補(bǔ)場(chǎng)合的比較。模式5和模式7也能實(shí)現(xiàn)上述功能。

四、三維等間距PSO輸出

1.三維等間距PSO輸出示例

例程： 采用模式7，模式6是按指令設(shè)置的觸發(fā)距離周期輸出，模式7的輸出位置由TABLE的數(shù)據(jù)點(diǎn)控制，輸出位置更靈活，可實(shí)現(xiàn)上例等距輸出，也可實(shí)現(xiàn)靈活間隔的輸出。

RAPIDSTOP(2)
WAIT IDLE(0)
WAIT IDLE(1)
WAIT IDLE(2)
'基礎(chǔ)軸參數(shù)設(shè)置
BASE(0,1,2) '選擇XY軸
'ATYPE=4,4,4 '1-脈沖軸類(lèi)型，比較DPOS；4-帶編碼器反饋軸類(lèi)型，比較編碼器的反饋位置MPOS
UNITS=100,100,100
SPEED=100,100,100
ACCEL=1000,1000,1000
DECEL=1000,1000,1000
MERGE=ON,ON
SRAMP=50,50,50 's曲線速度平滑
OP(0,OFF)
'將當(dāng)前位置設(shè)置為0,0
DPOS=0,0,0
MPOS=0,0,0
FORCE_SPEED=60 'SP速度
MOVEABS(0,0,0) '運(yùn)動(dòng)到0位
WAIT IDLE
VECTOR_MOVED = 0 '插補(bǔ)矢量距離清0
DIM WidthTime,T_Startnum,Pointnum
WidthTime = 10000 '脈沖寬度10000us
T_Startnum = 0 '比較點(diǎn)起始table編號(hào)
Pointnum = 8 '比較點(diǎn)個(gè)數(shù)
TABLE(T_Startnum,10,30,50,70,90,110,130,150) '比較點(diǎn)坐標(biāo)設(shè)置，起始table位置T_Startnum，8個(gè)點(diǎn)
HW_PSWITCH2(2) '清空HW比較緩沖區(qū)
HW_PSWITCH2(7,0,ON,T_Startnum,T_Startnum+Pointnum-1) '模式7
HW_TIMER(2,WidthTime+100,WidthTime,1,OFF,0) '輸出觸發(fā)變成ON后，打開(kāi)WidthTime us后關(guān)閉輸出
DELAY(10)
TRIGGER '啟動(dòng)示波器
MOVEABS(100,80,90) '三軸直線插補(bǔ)
WAIT IDLE '等待運(yùn)動(dòng)停止
HW_PSWITCH2(2) '清空HW比較緩沖區(qū)
END

波器采樣波形如下：采樣6個(gè)通道的波形，依次為軸0的目標(biāo)位置，軸1的目標(biāo)位置，軸2的目標(biāo)位置，輸出口0，軸0軸1軸2插補(bǔ)的矢量合成位置，軸0軸1軸2插補(bǔ)的運(yùn)行速度。

Table存儲(chǔ)的比較點(diǎn)矢量位置為10,30,50,70,90,110,130,150，共8個(gè)點(diǎn)，每到一個(gè)點(diǎn)觸發(fā)比較，由HW_TIMER可精準(zhǔn)控制輸出脈沖的寬度，輸出頻率更快，整體精度更高。

審核編輯 黃昊宇